daestrom wrote:

It looks like most snow melting systems aim at 100 Btu/h-ft^2 min, enough
to melt about 1" of snow per hour.

Darn!!! So when it snows over 6"/hour here (a near weekly occurance in
Jan/Feb), I'm out of luck :-/

http://www.geothermie.de/egec-geothe...ow_melting.htm

....describes a Japanese system in which 60 F water circulates through
a heat exchanger under a sidewalk, melts off snow, cools to 45 F, then
gets sprinkled onto the road next to the sidewalk.

The batch simulation below seems to indicate that a groundwater system with
a 2'x2' trench on one side of a driveway might keep up with 10"/hour of snow,
not counting the useful energy in the original trenchful of water. It seems
to do surprisingly well, with a 3.3 hour layer time constant and 0.1 hour
timesteps. The 10" of snow over a 10' wide x 1' long strip of driveway is
like 53 pounds of ice, which requires 7680 Btu to melt, with no heat loss
to the outdoors (in this first-order model.) The first 4" layer of soil below
the trench has a heat capacity of 1361 Btu/F, so it (alone) can supply the
snow melting energy with a 7680/1361 = 5.6 F temperature drop, which is close
to the final temp drop in the simulation.

We might keep the soil under the trench damp in wintertime by measuring
its lengthwise conductance and automatically adding water as needed with
a solenoid valve when the soil conductance becomes too low.

Nick

20 SNOWDEPTH=10'(inches)
30 SNOWDENSITY=6.4'(lb/ft^3)
40 DRIVEWIDTH=10'feet
50 MELTLOAD=144*SNOWDEPTH/12*SNOWDENSITY*DRIVEWIDTH'(Btu)
60 TG=55'deep ground temp (F)
70 GC=20'damp soil conductivity (Btu-in/h-F-ft^2)
80 CG=50'damp soil heat capacity (Btu/F-ft^3)
90 RI=24'trench radius (inches)
100 THICKNESS=4'layer thickness (inches)
110 FOR LAYER = 0 TO 10'(10 is deepest)
120 RLAYER=RI+LAYER*THICKNESS/2'mean layer radius (inches)
130 SLAYER=3.14159*RLAYER'mean layer surface (ft^2)
140 R(LAYER)=THICKNESS/GC/SLAYER'layer resistance (h-F/Btu)
150 VLAYER=SLAYER*THICKNESS/12'layer volume (ft^3)
160 C(LAYER)=VLAYER*CG'layer capacitance (Btu/F)
170 TEMP(LAYER)=TG'initialize layer temps (F)
180 NEXT LAYER
190 DT=.1'timestep (h)
200 TEMP(0)=32'trench temp (F)
210 FOR LAYER = 0 TO 9
220 IF LAYER=0 THEN Q=0:GOTO 240
230 Q=-(TEMP(LAYER)-TEMP(LAYER-1))/R(LAYER-1)*DT'heatflow out of layer (Btu)
240 Q(LAYER)=Q+(TEMP(LAYER+1)-TEMP(LAYER))/R(LAYER)*DT'flow into layer (Btu)
250 TEMP(LAYER)=TEMP(LAYER)+Q(LAYER)/C(LAYER)'new layer temp (F)
260 NEXT LAYER
270 T=T+DT'elapsed time (h)
280 ICEMELT=ICEMELT+Q(0)'total ice melting energy (Btu)
290 IF ICEMELTMELTLOAD GOTO 200'melt more ice...
300 PRINT SNOWDEPTH,T
310 TEMP(0)=32'trench temp (F)
320 FOR LAYER=0 TO 10'final temp distribution in layers
330 PRINT LAYER,TEMP(LAYER)
340 NEXT LAYER

snow depth melting time
(inches) (hours)

10 1

layer # layer temp (F)

0 32
1 50.12458 --This barely uses the first layer's energy...
2 54.31883
3 54.92732
4 54.99355
5 54.9995
6 54.99996
7 55
8 55
9 55
10 55