People still doubt that houses can be close to 100% solar heated outside of
the Southwest, inexpensively. Here's another 8' D-cube that might be deployed
to regional Infestations of Doubt, with 2" double-foil polyisocyanurate walls
and ceiling and an 8'x8' layer of Thermaglas Plus twinwall polycarbonate over
the south wall and 0.44 inches of water under the ceiling and 6.86" of water
in a 6'x6' EPDM-rubber-lined cloudy day heat storage tank under the floor.

On an average day, thermosyphoning sunspace air would heat the ceiling mass
to about 160 F, and it would cool to about 80 by dawn. A room temp thermostat
with a 2-watt damper motor would rotate foil foamboard louvers below the mass
to keep the room 70 F by radiation. On a cloudy day, a low-power pump would
move hot water up from the floor tank through the ceiling.

20 TA=30'outdoor temp (F)
30 TI=70'indoor temp (F)
40 SS=1000'south sun (Btu/ft^2-day)
50 TAU=.8'south glazing solar transmission
60 UVG=.58'south glazing U-value
70 SUN=64*TAU*SS'sun in (Btu/day)
80 RVW=15.5'wall R-value
90 RVS=RVW+1/UVG'south wall R-value
100 HC=(TI-TA)*64*(1/RVS+3/RVW)'required ceiling heat (Btu/h)
110 GC=4*1.714E-09*(TI+5+460)^3'min ceiling rad conductance (Btu/h-F-ft^2)
120 TMIN=TI+HC/GC/64'min ceiling temp (F)
130 SWNL=18*(TI-TA)*64/RVS'south wall night loss (Btu)
140 OWL=24*(TI-TA)*3*64/RVW'other wall loss (Btu/day)
150 RC=15.5'ceiling R-value
160 NETSUN=SUN-SWNL-OWL+6*TA*64*UVG-(TMIN/2-TA)*64/RC'net sun (Btu/day)
170 TS=NETSUN/(6*64*UVG+12*64/RC)'sunspace day temp (F)
180 TC=(TS+TMIN)/2'est. average ceiling temp (F)
190 ONH=SWNL+.75*OWL+18*(TC-TA)/RC'overnight heat (Btu)
200 C=ONH/(TS-TMIN)'ceiling mass (Btu/F)
210 DW=12*C/62.33/64'ceiling water depth (inches)
220 CDH=(TI-TA)*64*(1/RVS+3/RVW)+(TMIN-TA)*64/RC'cloudy day heat (Btu/h)
230 CD5=5*24*CDH'heat for 5 cloudy days (Btu)
240 CC=CD5/(TS-TMIN)'cloudy day capacitance (Btu/F)
250 CTD=12*CC/62.33/36'cloudy day floor tank depth (inches)
260 PRINT TS,TMIN
270 PRINT C,DW,CTD

sunspace min ceiling
temp (F) temp (F)

158.9396 79.58628

ceiling water depths (inches)
cap (Btu/F) ceiling floor

147.4126 .443444 6.864856

Nick