On Aug 1, 7:42 am, wrote:
Dave wrote:

...

I'm looking for an alternative to an air conditioning unit to lower
the temperature of a 260 sq.ft. room by about 10 degrees.

A 16'x16'x8' room with R20 insulation all round and a thermal conductance
of 768ft^2/R20 = 38.4 Btu/h-F would only need Q = 10x38.4 = 384 Btu/h of
net cooling to lower the room temp 10 F.

If it's Ta (F) outdoors with a wa humidity ratio and 80 F indoors with
wi = 0.012 pounds of water per pound of dry air (an efficient corner of
the ASHRAE comfort zone), evaporating P lb/h of water while ventilating
with C cfm of 0.075 lb/ft^3 outdoor air makes P = 60C0.075(0.012-wa) and
1000P = Q+(Ta-80)C. Dagget CA in August with Ta = 87.1 F and wa = 0.0077
makes P = 0.0194C and 1000P = 384+7.1C, so P = 0.61 lb/h and C = 31 cfm.

Fresh air might come from 2 vents with an 8' height difference. If 31 cfm
= 16.6Asqrt(8'x(87.1-80)) (an empirical chimney formula), A = 0.25 ft^2,
eg 6"x6" vents. Outdoor air with Pa = 29.921/(1+0.62198/wa) = 0.366"Hg,
and Pw = 0.566"Hg indoors and 0.61 = 0.1A(Pw-Pa) (an ASHRAE pool formula)
makes A = 30 ft^2, eg an 8'x8" diameter 2-sided porous shower curtain below
the upper vent with a 10 watt fountain pump moving 1 gpm from a sump with
a float valve up over the curtain whenever the room temp rises to 80 F.

Or maybe a 5' tall x 8" diameter nuclear bong cooler (see wiki :-)

20 PI=4*ATN(1)
30 AS=10'screen evap area (ft^2)
40 CW=2*8.33*60'water flow rate (lb/h)
50 TW(0)=70'initial water temp (F)
60 CA=665'inlet airflow (cfm)
70 FA=PI*(8/24)^2'duct free area (ft^2)
80 VA=CA/FA/88'air velocity (mph)
90 UA=2+VA/2'airfilm conductance (Btu/h-F-ft^2)
100 TA(0)=100'inlet air temp (F)
110 PA=.1*EXP(17.863-9621/(100+460))'air vapor pressure ("Hg)
120 W(0)=.62198/(29.921/PA-1)'inlet air humidity ratio
140 QTC=0:QTE=0'initialize total heatflows (Btu/h)
150 FOR S=0 TO 9'evap screen number (0 is first)
160 QC=(TW(S)-TA(S))*UA*AS'water-air convective heatflow (Btu/h)
170 QTC=QTC+QC'total convective heatflow (Btu/h)
180 PW=EXP(17.863-9621/(TW(S)+460))'water vapor pressure ("Hg)
190 PA=29.921/(1+.62198/W(S))'air vapor pressure ("Hg)
200 BOWEN=99.4*(PW-PA)/(TW(S)-TA(S))'Bowen's ratio ("Hg/F)
210 QE=QC*BOWEN'water-air evaporative heatflow (Btu/h)
220 QTE=QTE+QE'total evaporative heatflow (Btu/h)
230 W(S+1)=W(S)+QE/(60*CA*.075*1000)'hum rat leaving screen
240 TA(S+1)=TA(S)+QC/CA'exit screen air temp (F)
250 TW(S+1)=TW(S)-(QC+QE)/CW'exit screen water temp (F)
260 NEXT
270 TW(0)=TW(0)-(QTC+QTE)/CW'new water temp (F)
280 IF ABS(QTE-QTEL).01 THEN QTEL=QTE:GOTO 140
290 FOR S=0 TO 10
300 PRINT TW(S),TA(S)
310 NEXT S
320 PRINT QTE

water temp (F) air temp (F)

62.82701 100
62.68013 92.83129
62.66226 87.01672
62.68551 82.32003
62.71742 78.53357
62.74708 75.48347
62.77165 73.02729
62.7911 71.04951
62.80624 69.4569
62.81795 68.17434
62.82701 67.14138

21850.99 Btu/h

Nick

Thanks Nick. It's a long time since I've seen a BASIC program
listing. I shouldn't have thrown out that Commodore VIC-20.

;-)