Chris Friesen wrote:

People still doubt that houses can be close to 100% solar heated outside of
the Southwest, inexpensively.

I'd like to see the numbers for Saskatoon, SK, Canada.

Energy Plus stats say 1007 Wh/m^2 of sun (472 diffuse) falls on the ground
on an average -13.7 C day in December in (52 N lat) Saskatoon... which leads
to a D-cube with another inch of foamboard and a little more mass:

10 SCREEN 9:KEY OFF:PI=4*ATN(1)
20 LD=52+10/60'north latitude (degrees)
30 L=LD*PI/180'radians
40 DECD=-23'December declination (degrees)
50 DEC=DECD*PI/180'radians
60 X=-TAN(L)*TAN(DEC)
70 HSR=ATN(X/SQR(-X*X+1))-PI/2'sunrise hour angle -arccos(x) (radians)
80 BETAD=90'surface tilt (degrees)
90 BETA=BETAD*PI/180'radians
100 NUM=COS(L-BETA)*COS(DEC)*SIN(HSR)+HSR*SIN(L-BETA)*SIN(DEC)
110 DEN=COS(L)*COS(DEC)*SIN(HSR)+HSR*SIN(L)*SIN(DEC)
120 RB=NUM/DEN'tilted surface to horizontal beam rad rat
130 RD=(1+COS(BETA))/2'tilted to horizontal diff rad rat
140 RHOG=.6'ground reflectivity
150 RR=RHOG*SIN(BETA/2)*SIN(BETA/2)'ground reflectance factor
160 IGLOH=1.007*317.1'global horizontal radiation (Btu/ft^2)
170 IDIFH=.472*317.1'diffuse horizontal radiation (Btu/ft^2)
180 IBEAMH=IGLOH-IDIFH'beam horizontal radiation (Btu/ft^2)
190 SS=RB*IBEAMH+RD*IDIFH+RR*IGLOH'south sun (Btu/ft^2-day)
200 TAU=.8'south glazing solar transmission
210 UVG=.58'south glazing U-value
220 SUN=64*TAU*SS'sun in (Btu/day)
230 RVW=22.7'wall R-value
240 RVS=RVW+1/UVG'south wall R-value
250 TA=1.8*(-13.7)+32'outdoor temp (F)
260 TI=70'indoor temp (F)
270 HC=(TI-TA)*64*(1/RVS+3/RVW)'required ceiling heat (Btu/h)
280 GC=4*1.714E-09*(TI+5+460)^3'min ceiling rad conductance (Btu/h-F-ft^2)
290 TMIN=TI+HC/GC/64'min ceiling temp (F)
300 SWNL=18*(TI-TA)*64/RVS'south wall night loss (Btu)
310 OWL=24*(TI-TA)*3*64/RVW'other wall loss (Btu/day)
320 RC=RVW'ceiling R-value
330 NETSUN=SUN-SWNL-OWL+6*TA*64*UVG-(TMIN/2-TA)*64/RC'net sun (Btu/day)
340 TS=NETSUN/(6*64*UVG+12*64/RC)'sunspace day temp (F)
350 TC=(TS+TMIN)/2'est. average ceiling temp (F)
360 ONH=SWNL+.75*OWL+18*(TC-TA)/RC'overnight heat (Btu)
370 C=ONH/(TS-TMIN)'ceiling mass (Btu/F)
380 DW=12*C/62.33/64'water depth (inches)
390 CDH=(TI-TA)*64*(1/RVS+3/RVW)+(TMIN-TA)*64/RC'cloudy day heat (Btu/h)
400 CD5=5*24*CDH'heat for 5 cloudy days (Btu)
410 CC=CD5/(TS-TMIN)'cloudy day capacitance (Btu/F)
420 CTD=12*CC/62.33/36'cloudy day tank depth (inches)
430 PRINT TS,TMIN
440 PRINT C,DW,CTD

sunspace min ceiling
temp (F) temp (F)

151.1164 80.33141

ceiling water depths (inches)
cap (Btu/F) ceiling floor

177.7378 .5346678 8.159242

The next step might be a TMY2 simulation with hourly Energy Plus data.

Nick